package bonsai

  1. Overview
  2. Docs
package bonsai
Legend:
Page
Library
Module
Module type
Parameter
Class
Class type
Source

Source file flatten_values.ml

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
open! Core
open! Import

let value_map (type a) ({ value; here; id } : a Value.t) =
  let value =
    match value with
    | Map
        { f
        ; t =
            { value =
                Both
                  ( t1
                  , { value =
                        Both
                          ( t2
                          , { value =
                                Both
                                  ( t3
                                  , { value =
                                        Both
                                          ( t4
                                          , { value =
                                                Both (t5, { value = Both (t6, t7); _ })
                                            ; _
                                            } )
                                    ; _
                                    } )
                            ; _
                            } )
                    ; _
                    } )
            ; _
            }
        } ->
      Value.Map7
        { f = (fun t1 t2 t3 t4 t5 t6 t7 -> f (t1, (t2, (t3, (t4, (t5, (t6, t7)))))))
        ; t1
        ; t2
        ; t3
        ; t4
        ; t5
        ; t6
        ; t7
        }
    | Map
        { f
        ; t =
            { value =
                Both
                  ( t1
                  , { value =
                        Both
                          ( t2
                          , { value =
                                Both
                                  ( t3
                                  , { value = Both (t4, { value = Both (t5, t6); _ }); _ }
                                  )
                            ; _
                            } )
                    ; _
                    } )
            ; _
            }
        } ->
      Map6
        { f = (fun t1 t2 t3 t4 t5 t6 -> f (t1, (t2, (t3, (t4, (t5, t6))))))
        ; t1
        ; t2
        ; t3
        ; t4
        ; t5
        ; t6
        }
    | Map
        { f
        ; t =
            { value =
                Both
                  ( t1
                  , { value =
                        Both (t2, { value = Both (t3, { value = Both (t4, t5); _ }); _ })
                    ; _
                    } )
            ; _
            }
        } ->
      Map5
        { f = (fun t1 t2 t3 t4 t5 -> f (t1, (t2, (t3, (t4, t5))))); t1; t2; t3; t4; t5 }
    | Map
        { f
        ; t =
            { value = Both (t1, { value = Both (t2, { value = Both (t3, t4); _ }); _ })
            ; _
            }
        } -> Map4 { f = (fun t1 t2 t3 t4 -> f (t1, (t2, (t3, t4)))); t1; t2; t3; t4 }
    | Map { f; t = { value = Both (t1, { value = Both (t2, t3); _ }); _ } } ->
      Map3 { f = (fun t1 t2 t3 -> f (t1, (t2, t3))); t1; t2; t3 }
    | Map { f; t = { value = Both (t1, t2); _ } } ->
      Map2 { f = (fun t1 t2 -> f (t1, t2)); t1; t2 }
    | Both
        ( t1
        , { value =
              Both
                ( t2
                , { value =
                      Both
                        ( t3
                        , { value =
                              Both
                                ( t4
                                , { value = Both (t5, { value = Both (t6, t7); _ }); _ }
                                )
                          ; _
                          } )
                  ; _
                  } )
          ; _
          } ) ->
      Map7
        { f = (fun t1 t2 t3 t4 t5 t6 t7 -> t1, (t2, (t3, (t4, (t5, (t6, t7))))))
        ; t1
        ; t2
        ; t3
        ; t4
        ; t5
        ; t6
        ; t7
        }
    | Both
        ( t1
        , { value =
              Both
                ( t2
                , { value =
                      Both (t3, { value = Both (t4, { value = Both (t5, t6); _ }); _ })
                  ; _
                  } )
          ; _
          } ) ->
      Map6
        { f = (fun t1 t2 t3 t4 t5 t6 -> t1, (t2, (t3, (t4, (t5, t6)))))
        ; t1
        ; t2
        ; t3
        ; t4
        ; t5
        ; t6
        }
    | Both
        ( t1
        , { value = Both (t2, { value = Both (t3, { value = Both (t4, t5); _ }); _ }); _ }
        ) ->
      Map5 { f = (fun t1 t2 t3 t4 t5 -> t1, (t2, (t3, (t4, t5)))); t1; t2; t3; t4; t5 }
    | Both (t1, { value = Both (t2, { value = Both (t3, t4); _ }); _ }) ->
      Map4 { f = (fun t1 t2 t3 t4 -> t1, (t2, (t3, t4))); t1; t2; t3; t4 }
    | Both (t1, { value = Both (t2, t3); _ }) ->
      Map3 { f = (fun t1 t2 t3 -> t1, (t2, t3)); t1; t2; t3 }
    | v -> v
  in
  { Value.value; here; id }
;;

module Types = struct
  module Down = Unit
  module Acc = Unit
  module Up = Fix_transform.Unit
end

module Flatten_values (Recurse : Fix_transform.Recurse with module Types := Types) =
struct
  let transform_v () () v =
    let out = value_map v in
    Recurse.on_value () () `Skipping_over out
  ;;

  let transform_c () () c = Recurse.on_computation () () `Skipping_over c
end

open Fix_transform.Make (Types) (Flatten_values)

let flatten_values c =
  let (), (), r = Trampoline.run (transform_c () () c) in
  r
;;