package bonsai

  1. Overview
  2. Docs
package bonsai
Legend:
Page
Library
Module
Module type
Parameter
Class
Class type
Source

Source file form_manual.ml

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
open! Core
open Bonsai_web
open Bonsai.Let_syntax

type ('a, 'view) t =
  { value : 'a Or_error.t
  ; view : 'view
  ; set : 'a -> unit Vdom.Effect.t
  }
[@@deriving fields ~getters]

let value_or_default t ~default = t |> value |> Or_error.ok |> Option.value ~default

let normalize { value; set; view = _ } =
  match value with
  | Ok value -> set value
  | Error _ -> Ui_effect.Ignore
;;

let view t = t.view
let map_view t ~f = { t with view = f t.view }
let is_valid t = Or_error.is_ok t.value

let return ?sexp_of_t ?(equal = phys_equal) value =
  let set new_value =
    (* Only log a message if someone tried to set a non-equal value. This prevents
       superfluous messages when e.g. someone sets a unit into a unit form. *)
    if phys_equal value new_value || equal value new_value
    then Effect.Ignore
    else (
      match sexp_of_t with
      | Some sexp_of_t ->
        Effect.print_s
          [%message "Form.return was set, but setting is ignored." ~set_value:(value : t)]
      | None -> Effect.print_s [%message "Form.return was set, but setting is ignored."])
  in
  { value = Ok value; view = (); set }
;;

let return_settable ?sexp_of_model ~equal value =
  let%sub value, set_value = Bonsai.state value ?sexp_of_model ~equal in
  let%arr value = value
  and set_value = set_value in
  { value = Ok value; view = (); set = set_value }
;;

let return_error error =
  { value = Error error; view = (); set = (fun _ -> Ui_effect.Ignore) }
;;

let map_error t ~f = { t with value = t.value |> Result.map_error ~f }

let both a b =
  let value = Or_error.both a.value b.value in
  let view = a.view, b.view in
  let set (ea, eb) = Effect.lazy_ (lazy (Ui_effect.Many [ a.set ea; b.set eb ])) in
  { value; view; set }
;;

let all forms =
  let values, view = List.map forms ~f:(fun a -> a.value, a.view) |> List.unzip in
  let value = Or_error.all values in
  let set edits =
    Effect.lazy_
      (lazy
        (let paired, remainder = List.zip_with_remainder forms edits in
         let error_message =
           match remainder with
           | None -> Effect.Ignore
           | Some mismatch ->
             let form_count = List.length forms in
             let edits_count = List.length edits in
             let print_warning detail resolution =
               Effect.print_s
                 [%message
                   {|WARNING: Form.set called on result of Form.all with a list value whose length doesn't match the number of forms |}
                     detail
                     (form_count : int)
                     (edits_count : int)
                     resolution]
             in
             (match mismatch with
              | First (_ : _ t list) ->
                print_warning "more forms than values" "not setting left-over forms"
              | Second (_ : _ list) ->
                print_warning "more values than forms" "dropping left-over values")
         in
         Ui_effect.Many (error_message :: List.map paired ~f:(fun (a, edit) -> a.set edit))))
  in
  { value; view; set }
;;

let all_map (type k cmp) (forms : (k, _, cmp) Map.t) =
  let comparator = Map.comparator_s forms in
  let module C = (val comparator) in
  let values, views =
    Map.to_alist forms
    |> List.map ~f:(fun (k, form) ->
         let value =
           let%map.Or_error value = form.value in
           k, value
         in
         value, (k, form.view))
    |> List.unzip
  in
  let value = values |> Or_error.all |> Or_error.map ~f:(Map.of_alist_exn comparator) in
  let view = Map.of_alist_exn comparator views in
  let set edits =
    Effect.lazy_
      (lazy
        (let updates =
           Map.fold2 forms edits ~init:[] ~f:(fun ~key ~data acc ->
             let warning_m details =
               Effect.print_s
                 [%message
                   {|WARNING: Form.set on the result of Form.all_map has mismatched keys|}
                     ~_:(details : string)
                     ~key:(C.comparator.sexp_of_t key : Sexp.t)]
             in
             match data with
             | `Left _form ->
               let eff = warning_m "update is missing key present in active form" in
               eff :: acc
             | `Right _update ->
               let eff = warning_m "update contains key not present in active forms" in
               eff :: acc
             | `Both (form, update) -> form.set update :: acc)
         in
         Effect.Many updates))
  in
  { value; view; set }
;;

let project' ?(extend_view_with_error = fun view _error -> view) t ~parse ~unparse =
  let value, view =
    match t.value with
    | Ok a ->
      (match Or_error.try_with_join (fun () -> parse a) with
       | Ok a -> Ok a, t.view
       | Error e -> Error e, extend_view_with_error t.view e)
    | Error _ as e -> e, t.view
  in
  let set a = Effect.lazy_ (lazy (t.set (unparse a))) in
  { value; view; set }
;;

let validate ?extend_view_with_error t ~f =
  project'
    t
    ?extend_view_with_error
    ~parse:(fun a -> f a |> Or_error.map ~f:(fun () -> a))
    ~unparse:Fn.id
;;

let project ?extend_view_with_error t ~parse_exn ~unparse =
  project' t ?extend_view_with_error ~parse:(fun a -> Ok (parse_exn a)) ~unparse
;;

let optional' (type a b) (t : (a, _) t) ~parse ~unparse ~none : (b option, _) t =
  project' t ~parse ~unparse:(Option.value_map ~default:none ~f:unparse)
;;

let optional t ~is_some ~none =
  let parse a = if is_some a then Ok (Some a) else Ok None in
  optional' t ~parse ~unparse:Fn.id ~none
;;

let fallback_to t ~value =
  match t.value with
  | Ok _ -> t
  | Error _ -> { t with value = Ok value }
;;

module Dynamic = struct
  let with_default_from_effect effect form =
    let open Bonsai.Let_syntax in
    let%sub is_loaded, set_is_loaded =
      Bonsai.state false ~sexp_of_model:[%sexp_of: Bool.t] ~equal:[%equal: Bool.t]
    in
    let%sub () =
      match%sub is_loaded with
      | true -> Bonsai.const ()
      | false ->
        let%sub after_display =
          let%arr effect = effect
          and set_is_loaded = set_is_loaded
          and form = form in
          let%bind.Effect default = effect in
          Ui_effect.Many [ set form default; set_is_loaded true ]
        in
        Bonsai.Edge.lifecycle ~after_display ()
    in
    return form
  ;;

  let sync_with ?sexp_of_model ~equal ~store_value ~store_set form =
    let%sub interactive_value, interactive_set =
      let%arr form = form in
      Or_error.ok (value form), set form
    in
    Bonsai_extra.mirror'
      ()
      ?sexp_of_model
      ~equal
      ~store_value
      ~store_set
      ~interactive_value
      ~interactive_set
  ;;

  let with_default default form =
    let%sub get_default = Bonsai.yoink default in
    let%sub effect =
      let%arr get_default = get_default in
      match%bind.Effect get_default with
      | Active default -> Effect.return default
      | Inactive -> Effect.never
    in
    with_default_from_effect effect form
  ;;

  let with_default_always default form =
    let open Bonsai.Let_syntax in
    let%sub is_loaded, set_is_loaded =
      Bonsai.state false ~sexp_of_model:[%sexp_of: Bool.t] ~equal:[%equal: Bool.t]
    in
    let%sub () =
      match%sub is_loaded with
      | true -> Bonsai.const ()
      | false ->
        let%sub after_display =
          let%arr default = default
          and set_is_loaded = set_is_loaded
          and { set; _ } = form in
          Effect.lazy_ (lazy (Ui_effect.Many [ set default; set_is_loaded true ]))
        in
        Bonsai.Edge.lifecycle ~after_display ()
    in
    let%sub () =
      let%sub on_activate =
        let%arr default = default
        and { set; _ } = form
        and is_loaded = is_loaded in
        if is_loaded then Effect.lazy_ (lazy (set default)) else Effect.Ignore
      in
      Bonsai.Edge.lifecycle ~on_activate ()
    in
    return form
  ;;

  let on_change
    (type a)
    ?(on_error = Value.return (Fn.const Ui_effect.Ignore))
    ?sexp_of_model
    ~equal
    ~f
    value_to_watch
    =
    let module M_or_error = struct
      type model = a

      let equal_model = equal
      let sexp_of_model = Option.value ~default:sexp_of_opaque sexp_of_model

      type t = model Or_error.t [@@deriving equal, sexp_of]
    end
    in
    let callback =
      let%map f = f
      and on_error = on_error in
      function
      | Error e -> on_error e
      | Ok new_value -> f new_value
    in
    Bonsai.Edge.on_change
      ~sexp_of_model:[%sexp_of: M_or_error.t]
      ~equal:[%equal: M_or_error.t]
      (value_to_watch >>| value)
      ~callback
  ;;

  let project_via_effect
    (type a b view)
    ?sexp_of_input
    ?sexp_of_result
    ~equal_input
    ~equal_result
    ?(one_at_a_time = false)
    ?debounce_ui
    (t : (a, view) t Bonsai.Value.t)
    ~unparse
    ~parse
    =
    let open Bonsai.Effect_throttling in
    let module Validated = struct
      let equal_a = equal_input
      let equal_b = equal_result

      type t = (a * b) Or_error.t Poll_result.t [@@deriving equal]
    end
    in
    let value = t >>| value in
    let%sub validation =
      let%sub parse =
        if one_at_a_time
        then poll parse
        else (
          let%arr parse = parse in
          fun a ->
            let%map.Effect result = parse a in
            Poll_result.Finished result)
      in
      let%sub effect =
        let%arr parse = parse in
        function
        | Error e -> Poll_result.Finished (Error e) |> Ui_effect.return
        | Ok a ->
          (match%map.Effect parse a with
           | Aborted -> Poll_result.Aborted
           | Finished (Ok b) -> Finished (Ok (a, b))
           | Finished (Error e) -> Finished (Error e))
      in
      let sexp_of_result =
        let f sexp_of_input sexp_of_result =
          Poll_result.sexp_of_t
            (Or_error.sexp_of_t (sexp_of_pair sexp_of_input sexp_of_result))
        in
        Option.map2 sexp_of_input sexp_of_result ~f
      in
      Bonsai.Edge.Poll.effect_on_change
        ?sexp_of_input:(Option.map sexp_of_input ~f:Or_error.sexp_of_t)
        ?sexp_of_result
        ~equal_input:(Or_error.equal equal_input)
        ~equal_result:[%equal: Validated.t]
        Bonsai.Edge.Poll.Starting.empty
        value
        ~effect
    in
    let%sub is_stable =
      match%sub value with
      | Error _ -> Bonsai.const false
      | Ok value ->
        (match debounce_ui with
         | None -> Bonsai.const true
         | Some time_to_stable ->
           Bonsai_extra.is_stable
             ~equal:equal_input
             value
             ~time_to_stable:(Value.return time_to_stable))
    in
    let%arr t = t
    and validation = validation
    and is_stable = is_stable in
    let validating_error = Error (Error.of_string "validating...") in
    project'
      t
      ~parse:(fun x ->
        if not is_stable
        then validating_error
        else (
          match validation with
          | Some (Finished (Ok (a, b))) when equal_input a x -> Ok b
          | None | Some Aborted | Some (Finished (Ok _)) -> validating_error
          | Some (Finished (Error e)) -> Error e))
      ~unparse
  ;;

  let validate_via_effect
    (type a view)
    ?sexp_of_model
    ~equal
    ?one_at_a_time
    ?debounce_ui
    (t : (a, view) t Bonsai.Value.t)
    ~f
    =
    let%sub parse =
      let%arr f = f in
      fun value ->
        let%bind.Effect validation = f value in
        Effect.return
          (let%bind.Or_error () = validation in
           Ok value)
    in
    project_via_effect
      ?sexp_of_input:sexp_of_model
      ?sexp_of_result:sexp_of_model
      ~equal_input:equal
      ~equal_result:equal
      ?one_at_a_time
      ?debounce_ui
      t
      ~unparse:Fn.id
      ~parse
  ;;
end