Source file queryAlbum.ml

(*****************************************************************************)
(*                                                                           *)
(*  Copyright (C) 2026 Yves Ndiaye                                           *)
(*                                                                           *)
(* This Source Code Form is subject to the terms of the Mozilla Public       *)
(* License, v. 2.0. If a copy of the MPL was not distributed with this       *)
(* file, You can obtain one at https://mozilla.org/MPL/2.0/.                 *)
(*                                                                           *)
(*****************************************************************************)

open QueryUtil

let matches_node subfields (album, stats, participants) node =
  let id = SkhcDb.Album.id album in
  let album_name = SkhcDb.Album.name album in
  let sort_name = SkhcDb.Album.sort_name album in
  let flag = SkhcDb.Album.flag album in
  let year = SkhcDb.Album.year album in
  let rating = SkhcDb.Album.rating album in
  let genre = SkhcDb.Album.genre album in
  let cover_path = SkhcDb.Album.cover_path album in
  let created_at = SkhcDb.Album.created_at album in
  let modified_at = SkhcDb.Album.updated_at album in
  let duration = SkhcDb.Album.Stats.duration stats in
  let music_count = SkhcDb.Album.Stats.music_count stats in
  let play_count = SkhcDb.Album.Stats.play_count stats in
  let size = SkhcDb.Album.Stats.size stats in
  let avg_duration = SkhcDb.Album.Stats.avg_duration stats in
  let avg_rating = SkhcDb.Album.Stats.avg_rating stats in
  let avg_size = SkhcDb.Album.Stats.avg_size stats in
  match node with
  | Node.Substring s ->
      let fields = match_participants participants in
      let fields =
        fields
        |> add_single Title album_name
        |> add_single Album album_name
        |> add_field_if_some Genre genre
        |> add_field_if_some SortName sort_name
        |> Substrings.filter (fun key _ -> List.mem key subfields)
        |> Substrings.bindings |> List.map snd
      in
      List.exists (lmatches ~insensible:true false s) fields
  | Field (FString s) -> (
      let regex = Field.String.regex s in
      let insensible = Field.String.insensible s in
      let field = Field.String.key s in
      let value = Field.String.value s in
      match field with
      | Title | Album ->
          matches ~insensible regex value album_name
      | SortName ->
          omatches ~insensible regex value sort_name
      | Artist ->
          SkhcDb.Ids.Map.exists
            (fun _ (artist_name, roles) ->
              SkhcDb.Roles.mem Artist roles
              && matches ~insensible regex value artist_name
            )
            participants
      | AlbumArtist ->
          SkhcDb.Ids.Map.exists
            (fun _ (artist_name, roles) ->
              SkhcDb.Roles.mem AlbumArtist roles
              && matches ~insensible regex value artist_name
            )
            participants
      | Composer ->
          SkhcDb.Ids.Map.exists
            (fun _ (artist_name, roles) ->
              SkhcDb.Roles.mem Composer roles
              && matches ~insensible regex value artist_name
            )
            participants
      | Genre ->
          omatches ~insensible regex value genre
      | Path ->
          false
      | Arbitrary _ ->
          false
      | FileExtension ->
          false
    )
  | Field (FBool b) -> (
      let field = Field.Bool.key b in
      let b = Field.Bool.value b in
      match field with
      | Art ->
          let cover = Option.is_some cover_path in
          b = cover
      | Flag ->
          flag = b
    )
  | Field (FInt64 i64) -> (
      let field = Field.Int64.key i64 in
      let frange = Field.Int64.value i64 in
      match field with
      | Id ->
          Range.matches frange id
      | Size ->
          Range.matches frange size
    )
  | Field (FInt i) -> (
      let field = Field.Int.key i in
      let frange = Field.Int.value i in
      match field with
      | Year ->
          year
          |> Option.map (Range.matches frange)
          |> Option.value ~default:false
      | Plays ->
          Range.matches frange play_count
      | Length ->
          Range.matches frange duration
      | Rating ->
          rating
          |> Option.map (Range.matches frange)
          |> Option.value ~default:false
      | AlbumCount ->
          Range.matches frange music_count
      | Track ->
          false
      | Disc ->
          false
    )
  | Field (FFloat f) -> (
      let field = Field.Float.key f in
      let frange = Field.Float.value f in
      match field with
      | AvgDuration ->
          Range.matches frange avg_duration
      | AvgRating ->
          Range.matches frange avg_rating
      | AvgSize ->
          Range.matches frange avg_size
      | CreatedAt ->
          Range.matches frange created_at
      | ModifiedAt ->
          Range.matches frange modified_at
      | PlayedAt ->
          false
    )

let compare_key (reversed, key) lhs rhs =
  let module Strings = Set.Make (String) in
  let set_roles r map =
    SkhcDb.Ids.Map.fold
      (fun _ (name, roles) names ->
        if SkhcDb.Roles.mem r roles then
          Strings.add name names
        else
          names
      )
      map Strings.empty
  in
  let (labum, lstats, lroles), (ralbum, rstats, rroles) =
    if reversed then
      (rhs, lhs)
    else
      (lhs, rhs)
  in
  match key with
  | Field.FString s -> (
      let key = Field.String.key s in
      match key with
      | Title | Album ->
          String.compare (SkhcDb.Album.name labum) (SkhcDb.Album.name ralbum)
      | SortName ->
          Option.compare String.compare
            (SkhcDb.Album.sort_name labum)
            (SkhcDb.Album.sort_name ralbum)
      | Artist ->
          let lhs = set_roles Artist lroles in
          let rhs = set_roles Artist rroles in
          Strings.compare lhs rhs
      | AlbumArtist ->
          let lhs = set_roles AlbumArtist lroles in
          let rhs = set_roles AlbumArtist rroles in
          Strings.compare lhs rhs
      | Composer ->
          let lhs = set_roles Composer lroles in
          let rhs = set_roles Composer rroles in
          Strings.compare lhs rhs
      | Genre ->
          Option.compare String.compare (SkhcDb.Album.genre labum)
            (SkhcDb.Album.genre ralbum)
      | Path | FileExtension | Arbitrary _ ->
          0
    )
  | FBool b -> (
      let key = Field.Bool.key b in
      match key with
      | Art ->
          Bool.compare
            (Option.is_some @@ SkhcDb.Album.cover_path labum)
            (Option.is_some @@ SkhcDb.Album.cover_path ralbum)
      | Flag ->
          Bool.compare (SkhcDb.Album.flag labum) (SkhcDb.Album.flag ralbum)
    )
  | FInt64 i64 -> (
      let key = Field.Int64.key i64 in
      match key with
      | Id ->
          Int64.compare (SkhcDb.Album.id labum) (SkhcDb.Album.id ralbum)
      | Size ->
          Int64.unsigned_compare
            (SkhcDb.Album.Stats.size lstats)
            (SkhcDb.Album.Stats.size rstats)
    )
  | FInt i -> (
      let field = Field.Int.key i in
      match field with
      | Year ->
          Option.compare Int.compare (SkhcDb.Album.year labum)
            (SkhcDb.Album.year ralbum)
      | Plays ->
          (* Even on 32 bit system, 
             the max int is 2^{30} - 1 which is more the 1 billions, 
             so we have some before it overflows
          *)
          Int.compare
            (SkhcDb.Album.Stats.play_count lstats)
            (SkhcDb.Album.Stats.play_count rstats)
      | Length ->
          Int.compare
            (SkhcDb.Album.Stats.duration lstats)
            (SkhcDb.Album.Stats.duration rstats)
      | Rating ->
          Float.compare
            (SkhcDb.Album.Stats.avg_rating lstats)
            (SkhcDb.Album.Stats.avg_rating rstats)
      | AlbumCount ->
          Int.compare
            (SkhcDb.Album.Stats.music_count lstats)
            (SkhcDb.Album.Stats.music_count rstats)
      | Track | Disc ->
          0
    )
  | FFloat f -> (
      let key = Field.Float.key f in
      match key with
      | AvgDuration ->
          Float.compare
            (SkhcDb.Album.Stats.avg_duration lstats)
            (SkhcDb.Album.Stats.avg_duration rstats)
      | AvgRating ->
          Float.compare
            (SkhcDb.Album.Stats.avg_rating lstats)
            (SkhcDb.Album.Stats.avg_rating rstats)
      | AvgSize ->
          Float.compare
            (SkhcDb.Album.Stats.avg_size lstats)
            (SkhcDb.Album.Stats.avg_size rstats)
      | CreatedAt ->
          Float.compare
            (SkhcDb.Album.created_at labum)
            (SkhcDb.Album.created_at ralbum)
      | ModifiedAt ->
          Float.compare
            (SkhcDb.Album.updated_at labum)
            (SkhcDb.Album.updated_at ralbum)
      | PlayedAt ->
          Option.compare Float.compare
            (SkhcDb.Album.Stats.played_at lstats)
            (SkhcDb.Album.Stats.played_at rstats)
    )