Source file queryUtil.ml

(*****************************************************************************)
(*                                                                           *)
(*  Copyright (C) 2026 Yves Ndiaye                                           *)
(*                                                                           *)
(* This Source Code Form is subject to the terms of the Mozilla Public       *)
(* License, v. 2.0. If a copy of the MPL was not distributed with this       *)
(* file, You can obtain one at https://mozilla.org/MPL/2.0/.                 *)
(*                                                                           *)
(*****************************************************************************)

let add_single key value fields =
  Substrings.update key
    (function None -> Some [ value ] | Some _ -> Some [ value ])
    fields

let add_value_set key value fields =
  Substrings.update key
    (function None -> Some [ value ] | Some values -> Some (value :: values))
    fields

let add_field_if_some key field fields =
  match field with
  | None ->
      fields
  | Some t ->
      Substrings.update key
        (function None -> Some [ t ] | Some values -> Some (t :: values))
        fields

let re_compute ~insensible regex s =
  match regex with
  | true ->
      let opts = match insensible with true -> [ `ICase ] | false -> [] in
      Re.Posix.re ~opts s
  | false ->
      let re = Re.str s in
      let re = match insensible with true -> Re.no_case re | false -> re in
      re

let omatches ~insensible regex s =
  let re = re_compute ~insensible regex s in
  let re = Re.compile re in
  Option.fold ~none:false ~some:(Re.execp re)

let matches ~insensible regex s w =
  let re = re_compute ~insensible regex s in
  let re = Re.compile re in
  Re.execp re w

let lmatches ~insensible regex s w =
  let re = re_compute ~insensible regex s in
  let re = Re.compile re in
  List.exists (Re.execp re) w

let match_participants participants =
  SkhcDb.Ids.Map.fold
    (fun _ (artist_name, roles) ->
      SkhcDb.Roles.fold
        (fun role fields ->
          match role with
          | SkhcDb.Role.Artist ->
              add_value_set Artist artist_name fields
          | AlbumArtist ->
              add_value_set AlbumArtist artist_name fields
          | Composer ->
              add_value_set Composer artist_name fields
          | Unknown ->
              fields
        )
        roles
    )
    participants Substrings.empty