package logs

  1. Overview
  2. Docs
Logging infrastructure for OCaml

Install 

dune-project
 Dependency

erratique.ch Readme Changelog ISC License Edit opam file Versions (4)

Authors

  1. T
    The logs programmers

Maintainers

  1. Daniel Bünzli

Sources

logs-0.10.0.tbz
sha512=122b7a77bd07aee1e0cb8e07e82b195a12528cf015e72fa0dd5afaae26ce04bad9b29f32a6d3bd3547fe522b8a036608785e8adb900e31580a0d555719bbb7e7

doc/logs.cli/Logs_cli/index.html

Module Logs_cliSource

Cmdliner support for Logs.

See a full example.

Options for setting the report level

Sourceval level : ?env:Cmdliner.Cmd.Env.info -> ?docs:string -> unit -> Logs.level option Cmdliner.Term.t

level ?env ?docs () is a term for three Cmdliner options that can be used with Logs.set_level. The options are documented under docs (defaults to the default of Cmdliner.Arg.info).

The options work as follows:

  • -v or --verbose, if it appears once, the value of the term is Some Logs.Info and more than once Some Logs.Debug.
  • --verbosity=LEVEL, the value of the term is l where l depends on on LEVEL. Takes over the option -v.
  • -q or --quiet, the value of the term is None. Takes over the -v and --verbosity options.
  • If both options are absent the default value is Some Logs.warning

If env is provided, the default value in case all options are absent can be overridden by the corresponding environment variable.

Example

The following example shows how to setup Logs and Fmt so that logging is performed on standard outputs with ANSI coloring if these are ttys. The command line interface provides options to control the use of colors and the log reporting level.

let hello _ msg =
  Logs.app (fun m -> m "%s" msg);
  Logs.info (fun m -> m "End-user information.");
  Logs.debug (fun m -> m "Developer information.");
  Logs.err (fun m -> m "Something bad happened.");
  Logs.warn (fun m -> m "Something bad may happen in the future.");
  if Logs.err_count () > 0 then 1 else 0

let setup_log ~style_renderer ~level =
  Fmt_tty.setup_std_outputs ?style_renderer ();
  Logs.set_level level;
  Logs.set_reporter (Logs_fmt.reporter ())

(* Command line interface *)

open Cmdliner
open Cmdliner.Term.Syntax

let cmd =
  Cmd.make (Cmd.info "tool") @@
  let env = Cmd.Env.info "TOOL_VERBOSITY" in
  let+ style_renderer = Fmt_cli.style_renderer ()
  and+ level = Logs_cli.level ~env ()
  and+ msg =
    let doc = "The message to output."  in
    Arg.(value & pos 0 string "Hello horrible world!" & info [] ~doc)
  in
  setup_log ~style_renderer ~level;
  hello msg


let main () = Cmd.eval' cmd
let () = if !Sys.interactive then () else exit (main ())