Source file queryArtist.ml

(*****************************************************************************)
(*                                                                           *)
(*  Copyright (C) 2026 Yves Ndiaye                                           *)
(*                                                                           *)
(* This Source Code Form is subject to the terms of the Mozilla Public       *)
(* License, v. 2.0. If a copy of the MPL was not distributed with this       *)
(* file, You can obtain one at https://mozilla.org/MPL/2.0/.                 *)
(*                                                                           *)
(*****************************************************************************)

include QueryUtil

let matches_node _subfields (artist, albums, stats) node =
  let id = SkhcDb.Artist.id artist in
  let name = SkhcDb.Artist.name artist in
  let sort_name = SkhcDb.Artist.sort_name artist in
  let flag = SkhcDb.Artist.flag artist in
  let artwork = SkhcDb.Artist.artwork artist in
  let rating = SkhcDb.Artist.rating artist in
  let music_count = SkhcDb.Artist.Stats.music_count stats in
  let album_count = SkhcDb.Artist.Stats.album_count stats in
  let play_count = SkhcDb.Artist.Stats.play_count stats in
  let avg_duration = SkhcDb.Artist.Stats.avg_duration stats in
  let avg_rating = SkhcDb.Artist.Stats.avg_rating stats in
  let avg_size = SkhcDb.Artist.Stats.avg_size stats in
  let duration = SkhcDb.Artist.Stats.duration stats in
  let played_at = SkhcDb.Artist.Stats.played_at stats in
  let created_at = SkhcDb.Artist.created_at artist in
  let modified_at = SkhcDb.Artist.updated_at artist in
  match node with
  | Node.Substring s ->
      let insensible = true in
      let regex = false in
      matches ~insensible regex s name || omatches ~insensible regex s sort_name
  | Field (FString s) -> (
      let regex = Field.String.regex s in
      let insensible = Field.String.insensible s in
      let field = Field.String.key s in
      let value = Field.String.value s in
      match field with
      | SortName ->
          omatches ~insensible regex value sort_name
      | Title ->
          matches ~insensible regex value name
      | Artist ->
          matches ~insensible regex value name
      | Path ->
          matches ~insensible regex value name
      | AlbumArtist ->
          matches ~insensible regex value name
      | Composer ->
          matches ~insensible regex value name
      | Album ->
          SkhcDb.Ids.Map.exists
            (fun _ album_name -> matches ~insensible regex value album_name)
            albums
      | Genre ->
          false
      | Arbitrary _ ->
          false
      | FileExtension ->
          false
    )
  | Field (FBool b) -> (
      let field = Field.Bool.key b in
      let b = Field.Bool.value b in
      match field with
      | Flag ->
          flag = b
      | Art ->
          let cover = Option.is_some artwork in
          b = cover
    )
  | Field (FInt64 i64) -> (
      let field = Field.Int64.key i64 in
      let frange = Field.Int64.value i64 in
      match field with Id -> Range.matches frange id | Size -> false
    )
  | Field (FInt i) -> (
      let field = Field.Int.key i in
      let frange = Field.Int.value i in
      match field with
      | Rating ->
          rating
          |> Option.map (Range.matches frange)
          |> Option.value ~default:false
      | AlbumCount ->
          Range.matches frange album_count
      | Length ->
          Range.matches frange duration
      | Plays ->
          Range.matches frange play_count
      | MusicCount ->
          Range.matches frange music_count
      | Track | Year | Disc ->
          false
    )
  | Field (FFloat f) -> (
      let field = Field.Float.key f in
      let frange = Field.Float.value f in
      match field with
      | AvgDuration ->
          Range.matches frange avg_duration
      | AvgRating ->
          Range.matches frange avg_rating
      | AvgSize ->
          Range.matches frange avg_size
      | CreatedAt ->
          Range.matches frange created_at
      | ModifiedAt ->
          Range.matches frange modified_at
      | PlayedAt ->
          played_at
          |> Option.map (Range.matches frange)
          |> Option.value ~default:false
    )

let compare_key (r, key) lhs rhs =
  let lhs, rhs =
    if r then
      (rhs, lhs)
    else
      (lhs, rhs)
  in
  let lhs, _lalbum, lstats = lhs in
  let rhs, _ralbum, rstats = rhs in
  let cmp c f lhs rhs = c (f lhs) (f rhs) in
  let ocmp c f lhs rhs = Option.compare c (f lhs) (f rhs) in
  match key with
  | Field.(FString s) -> (
      let field = Field.String.key s in
      match field with
      | SortName ->
          ocmp String.compare SkhcDb.Artist.sort_name lhs rhs
      | Title | Artist | Path | AlbumArtist | Composer ->
          cmp String.compare SkhcDb.Artist.name lhs rhs
      | Album ->
          0
      | Genre ->
          0
      | Arbitrary _ ->
          0
      | FileExtension ->
          0
    )
  | FBool b -> (
      let field = Field.Bool.key b in
      match field with
      | Flag ->
          cmp Bool.compare SkhcDb.Artist.flag lhs rhs
      | Art ->
          cmp Bool.compare
            (fun s -> Option.is_some @@ SkhcDb.Artist.artwork s)
            lhs rhs
    )
  | FInt64 i64 -> (
      let field = Field.Int64.key i64 in
      match field with
      | Id ->
          cmp Int64.unsigned_compare SkhcDb.Artist.id lhs rhs
      | Size ->
          cmp Int64.unsigned_compare SkhcDb.Artist.Stats.size lstats rstats
    )
  | FInt i -> (
      let field = Field.Int.key i in
      match field with
      | Rating ->
          ocmp Int.compare SkhcDb.Artist.rating lhs rhs
      | Plays ->
          cmp Int.compare SkhcDb.Artist.Stats.play_count lstats rstats
      | AlbumCount ->
          cmp Int.compare SkhcDb.Artist.Stats.album_count lstats rstats
      | MusicCount ->
          cmp Int.compare SkhcDb.Artist.Stats.music_count lstats rstats
      | Length ->
          cmp Int.compare SkhcDb.Artist.Stats.duration lstats rstats
      | Track | Year | Disc ->
          0
    )
  | FFloat f -> (
      let field = Field.Float.key f in
      match field with
      | AvgDuration ->
          cmp Float.compare SkhcDb.Artist.Stats.avg_duration lstats rstats
      | AvgRating ->
          cmp Float.compare SkhcDb.Artist.Stats.avg_rating lstats rstats
      | AvgSize ->
          cmp Float.compare SkhcDb.Artist.Stats.avg_size lstats rstats
      | CreatedAt ->
          cmp Float.compare SkhcDb.Artist.created_at lhs rhs
      | ModifiedAt ->
          cmp Float.compare SkhcDb.Artist.updated_at lhs rhs
      | PlayedAt ->
          ocmp Float.compare SkhcDb.Artist.Stats.played_at lstats rstats
    )