Source file queryArtist.ml

(*****************************************************************************)
(*                                                                           *)
(*  Copyright (C) 2026 Yves Ndiaye                                           *)
(*                                                                           *)
(* This Source Code Form is subject to the terms of the Mozilla Public       *)
(* License, v. 2.0. If a copy of the MPL was not distributed with this       *)
(* file, You can obtain one at https://mozilla.org/MPL/2.0/.                 *)
(*                                                                           *)
(*****************************************************************************)

include QueryUtil

(* TODO: Change the query to compute other field. *)
let matches_node _subfields artist node =
  let id = SkhcDb.Artist.id artist in
  let name = SkhcDb.Artist.name artist in
  let sort_name = SkhcDb.Artist.sort_name artist in
  let flag = SkhcDb.Artist.flag artist in
  let artwork = SkhcDb.Artist.artwork artist in
  let rating = SkhcDb.Artist.rating artist in
  let created_at = SkhcDb.Artist.created_at artist in
  let modified_at = SkhcDb.Artist.updated_at artist in
  match node with
  | Node.Substring s ->
      let insensible = true in
      let regex = false in
      matches ~insensible regex s name || omatches ~insensible regex s sort_name
  | Field (FString s) -> (
      let regex = Field.String.regex s in
      let insensible = Field.String.insensible s in
      let field = Field.String.key s in
      let value = Field.String.value s in
      match field with
      | SortName ->
          omatches ~insensible regex value sort_name
      | Title ->
          matches ~insensible regex value name
      | Artist ->
          matches ~insensible regex value name
      | Path ->
          matches ~insensible regex value name
      | AlbumArtist ->
          matches ~insensible regex value name
      | Composer ->
          matches ~insensible regex value name
      | Album ->
          false
      | Genre ->
          false
      | Arbitrary _ ->
          false
      | FileExtension ->
          false
    )
  | Field (FBool b) -> (
      let field = Field.Bool.key b in
      let b = Field.Bool.value b in
      match field with
      | Flag ->
          flag = b
      | Art ->
          let cover = Option.is_some artwork in
          b = cover
    )
  | Field (FInt64 i64) -> (
      let field = Field.Int64.key i64 in
      let frange = Field.Int64.value i64 in
      match field with Id -> Range.matches frange id | Size -> false
    )
  | Field (FInt i) -> (
      let field = Field.Int.key i in
      let frange = Field.Int.value i in
      match field with
      | Rating ->
          rating
          |> Option.map (Range.matches frange)
          |> Option.value ~default:false
      | Track | Year | Plays | AlbumCount | Disc | Length ->
          false
    )
  | Field (FFloat f) -> (
      let field = Field.Float.key f in
      let frange = Field.Float.value f in
      match field with
      | AvgDuration | AvgRating | AvgSize ->
          false
      | CreatedAt ->
          Range.matches frange created_at
      | ModifiedAt ->
          Range.matches frange modified_at
      | PlayedAt ->
          (* When artist query will be more detailled. *)
          false
    )

let compare_key (r, key) lhs rhs =
  let lhs, rhs =
    if r then
      (rhs, lhs)
    else
      (lhs, rhs)
  in
  let cmp c f lhs rhs = c (f lhs) (f rhs) in
  let ocmp c f lhs rhs = Option.compare c (f lhs) (f rhs) in
  match key with
  | Field.(FString s) -> (
      let field = Field.String.key s in
      match field with
      | SortName ->
          ocmp String.compare SkhcDb.Artist.sort_name lhs rhs
      | Title | Artist | Path | AlbumArtist | Composer ->
          cmp String.compare SkhcDb.Artist.name lhs rhs
      | Album ->
          0
      | Genre ->
          0
      | Arbitrary _ ->
          0
      | FileExtension ->
          0
    )
  | FBool b -> (
      let field = Field.Bool.key b in
      match field with
      | Flag ->
          cmp Bool.compare SkhcDb.Artist.flag lhs rhs
      | Art ->
          cmp Bool.compare
            (fun s -> Option.is_some @@ SkhcDb.Artist.artwork s)
            lhs rhs
    )
  | FInt64 i64 -> (
      let field = Field.Int64.key i64 in
      match field with
      | Id ->
          cmp Int64.compare SkhcDb.Artist.id lhs rhs
      | Size ->
          0
    )
  | FInt i -> (
      let field = Field.Int.key i in
      match field with
      | Rating ->
          ocmp Int.compare SkhcDb.Artist.rating lhs rhs
      | Track | Year | Plays | AlbumCount | Disc | Length ->
          0
    )
  | FFloat f -> (
      let field = Field.Float.key f in
      match field with
      | AvgDuration | AvgRating | AvgSize ->
          0
      | CreatedAt ->
          cmp Float.compare SkhcDb.Artist.created_at lhs rhs
      | ModifiedAt ->
          cmp Float.compare SkhcDb.Artist.updated_at lhs rhs
      | PlayedAt ->
          0
    )