package dune-private-libs

  1. Overview
  2. Docs
Private libraries of Dune

Install 

dune-project
 Dependency

github.com Readme Changelog MIT License Edit opam file Versions (14)

Authors

  1. J
    Jane Street Group, LLC

Maintainers

  1. J
    Jane Street Group, LLC

Sources

dune-2.5.1.tbz
sha256=8f77d3a87f208e0d7cccaa1c48c4bb1bb87d62d07c3f25e9b8ba298e028ce52b
sha512=f209f12ced10c1abf8782bdb0143f4cec77795f7174d2cc75130afb1e01550b01f2f77b9e3ec4888efdad83d2f9878d179b39126f824f4e522f3ef4da34bf27e

doc/src/dune-private-libs.stdune/type_eq.ml.html

Source file type_eq.ml

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
type ('a, 'b) t = T : ('a, 'a) t

let cast (type a b) (T : (a, b) t) (x : a) : b = x

type ('a, 'b) eq = ('a, 'b) t

module Id = struct
  type _ w = ..

  module type T = sig
    type a

    type _ w += W : a w
  end

  type 'a t = (module T with type a = 'a)

  let hash (type a) ((module T) : a t) = Poly.hash T.W

  let equal (type a b) ((module M1) : a t) ((module M2) : b t) =
    match M1.W with
    | M2.W -> true
    | _ -> false

  let create (type a) () =
    ( ( module struct
        type nonrec a = a

        type _ w += W : a w
      end )
      : a t )

  let same (type a b) ((module M1) : a t) ((module M2) : b t) =
    match M1.W with
    | M2.W -> Some (T : (a, b) eq)
    | _ -> None
end