Module Bio_io.Fasta_in_channelSource

An input channel for reading FASTA files.

Overview

Quick start

• To get a list of records, use records or with_file_records.
• To get a sequence of records, use: record_sequence or with_file_record_sequence.
• To fold over records, use: fold_records or with_file_fold_records.
• To iterate over records, use: iter_records or with_file_iter_records.

For some more info, check out the usage examples.

Function flavors

Most functions in this module come in a few different flavors.

• Functions with with_file_ prefix
• Functions with the _exn suffix
• Functions that return Or_error.t

Functions that have the with_file_ prefix in their name take a filename string rather than a Fasta_in_channel.t. They are a convenient way to avoid wrapping your all your code in with_file function calls.

Functions that the _exn suffix in their name may raise exceptions, either from logic specific to this module, or from calls to other Core_kernel functions.

Functions that return Or_error.t catch all exceptions, even those not originating in the logic of this module. These functions shouldn't raise in practice. In other words, if you aren't using a function with _exn in the name, and you get an exception, then you have found a bug.

Here is an example of the different "flavors" of fold_records:

• fold_records: the normal Fasta_in_channel.t accepting, Or_error.t returning flavor
• fold_records_exn: takes Fasta_in_channel.t but may raise exceptions instead of returning Or_error.t
• with_file_fold_records: takes a file name (string) rather than a Fasta_in_channel.t, and returns Or_error.t
• with_file_fold_records_exn: takes a file name (string) rather than a Fasta_in_channel.t, and may raise exceptions

Examples

Return all records in a list

Simplest way. May raise exceptions.

 let records = Fasta_in_channel.with_file_records_exn fname 

A bit more involved, but you won't get exceptions. Instead, you have to handle the Or_error.t. One reason to do this is to give the user nicer error messages.

  let records =
    match Fasta_in_channel.with_file_records name with
    | Error err ->
        eprintf "Problem reading records: %s\n" (Error.to_string_hum err);
        exit 1
    | Ok records -> records

Iterating over records

Use the iter functions when you need to go over each record and perform some side-effects with them.

Print sequence IDs and sequence lengths

  let () =
    Fasta_in_channel.with_file_iter_records_exn "sequences.fasta"
      ~f:(fun record ->
        let open Fasta_record in
        printf "%s => %d\n" (id record) (String.length (seq record)))

Print sequence index, IDs, and sequence lengths.

This is like the last example except that we also want to print the index. The first record is 0, the 2nd is 1, etc.

  let () =
    Fasta_in_channel.with_file_iteri_records_exn "sequences.fasta"
      ~f:(fun index record ->
        let open Fasta_record in
        printf "%d: %s => %d\n" (index + 1) (id record)
          (String.length (seq record)))

Folding over records

If you need to reduce all the records down to a single value, use the fold functions.

Get total length of all sequences in the file.

Watch out as this may raise exceptions...see the _exn suffix.

  let total_length =
    Fasta_in_channel.with_file_fold_records_exn "sequences.fasta" ~init:0
      ~f:(fun length record ->
        let sequence = Fasta_record.seq record in
        length + String.length sequence)

Same thing, but this won't raise exceptions. You do have to handle Or_error.t to get the final value. Note that within the fold function, you get Fasta_record.t and not Fasta_record.t Or_error.t.

  let total_length =
    match
      Fasta_in_channel.with_file_fold_records name ~init:0
        ~f:(fun length record ->
          length + String.length (Fasta_record.seq record))
    with
    | Error err ->
        eprintf "Problem reading records: %s\n" (Error.to_string_hum err);
        exit 1
    | Ok total_length -> total_length

Pipelines with records

Sometimes you have a "pipeline" of computations that you need to do one after the other on records. In that case, use the sequence functions.

You could use Lists too, or just don't bother writing things in a pipeline, but with Sequenecs you can have your nice pipelines without all the extra intermediate allocations.

Here's a silly example.

In this case, I'm using the exception throwing versions.

  let () =
    Fasta_in_channel.with_file_exn name ~f:(fun chan ->
        Fasta_in_channel.record_sequence_exn chan
        (* Add sequence index to record description *)
        |> Sequence.mapi ~f:(fun i record ->
               let new_desc =
                 match Fasta_record.desc record with
                 | None -> Some (sprintf "sequence %d" i)
                 | Some old_desc ->
                     Some (sprintf "%s -- sequence %d" old_desc i)
               in
               Fasta_record.with_desc new_desc record)
        (* Convert all sequence chars to lowercase *)
        |> Sequence.map ~f:(fun record ->
               let new_seq = String.lowercase (Fasta_record.seq record) in
               Fasta_record.with_seq new_seq record)
        (* Print sequences *)
        |> Sequence.iter ~f:(fun record ->
               print_endline @@ Fasta_record.serialize record))

One thing to watch out for though...if you get an exception half way through and you are running side-effecting code like we are here then part of your side effects will have occured and part of them will not have occured.

There are also Or_error.t flavors of the sequence functions. Just watch out because these you actually do have to deal with Or_error.t for each Fasta_record.t in the sequence.

As an alternative, you could use the record_sequence_exn function, but wrap that in the with_file function. That way you don't have to deal with the Or_error.t inside your pipeline. Instead you deal with it at the end.

  let total_length =
    match
      Fasta_in_channel.with_file name ~f:(fun chan ->
          Fasta_in_channel.record_sequence_exn chan
          (* Blow up pipeline on second sequence. *)
          |> Sequence.mapi ~f:(fun i record ->
                 if i = 1 then assert false;
                 record)
          |> Sequence.fold ~init:0 ~f:(fun length record ->
                 length + String.length (Fasta_record.seq record)))
    with
    | Error err ->
        eprintf "Problem in parsing pipeline: %s\n"
          (Error.to_string_hum err);
        exit 1
    | Ok total_length -> total_length

As you can see, if that fasta file has more than one sequence it will hit the assert false and blow up.

API

Open/Close

Utilities

Getting records

As list

As sequence

These are a bit different:

* There are no with_file versions as you would have to do some fiddly things to keep the channel open, making them not so nice to use.

* Each Fasta_record.t that is yielded is wrapped in an Or_error.t. This is different from the iter, fold, and other non _exn functions in which case the entire result is wrapped in an Or_error.t, letting you ignore errors in the passed in ~f function and deal with failure once.

Folding over records

With index

These four functions are like their fold counterparts except that the folding function f is also passed the index of the current record.

Iterating over records

The iter functions are like the fold functions except they do not take an init value and the f function returns unit insead of some other value 'a (and thus return unit rather than a value 'a.

They are mainly called for side effects.

With index

The iteri variants are like the iter functions except that the function f is passed in the index of the current record.