package dkim

  1. Overview
  2. Docs

Source file sigs.ml

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
module type FUNCTOR = sig
  type 'a t
end

type (+'a, 't) io

type 't state = {
  bind : 'a 'b. ('a, 't) io -> ('a -> ('b, 't) io) -> ('b, 't) io;
  return : 'a. 'a -> ('a, 't) io;
}

type 't both = { f : 'a 'b. ('a, 't) io -> ('b, 't) io -> ('a * 'b, 't) io }

module type X = sig
  type 'a s
  type t

  external inj : 'a s -> ('a, t) io = "%identity"
  external prj : ('a, t) io -> 'a s = "%identity"
end

module Common = struct
  type t

  external inj : 'a -> 'b = "%identity"
  external prj : 'a -> 'b = "%identity"
end

module Make (T : FUNCTOR) = struct
  type 'a s = 'a T.t

  include Common
end

module type FLOW = sig
  type backend
  type flow

  val input : flow -> bytes -> int -> int -> (int, backend) io
end

module type STREAM = sig
  type backend
  type 'a t

  val create : unit -> 'a t * ('a option -> unit)
  val get : 'a t -> ('a option, backend) io
end

module type DNS = sig
  type backend
  type t

  val gettxtrrecord :
    t ->
    'a Domain_name.t ->
    ((string list, [> `Msg of string ]) result, backend) io
end